打开时超链接会更改地址-解网

问：

超链接 im Excel 数据： HTTPS://apply.d.co.uk/JobDetail/9467 但是当我点击它时，地址是： HTTPS://apply.d.co.uk/Error

我尝试检查 URL 是否正确，它总是说是，但是当我打开它时，它会发生变化并在地址中显示错误。

我使用了这个功能：

Function URLExists(url As String) As Boolean
    Dim Request As Object
    Dim ff As Integer
    Dim rc As Variant

    On Error GoTo EndNow
    Set Request = CreateObject("WinHttp.WinHttpRequest.5.1")

    With Request
      .Open "GET", url, False
      .Send
      rc = .StatusText
    End With
    Set Request = Nothing
    If rc = "OK" Then URLExists = True

    Exit Function
EndNow:
End Function

我只需要一个解决方案，这样我就不需要打开每个超链接来检查它是否显示错误。

////// 从高处到下面的解决方案有效！

Excel VBA 超链接

我使用了在stackoverflow上找到的函数：Function URLExists（url As String） As Boolean Dim Request As Object Dim ff As Integer Dim rc As Variant On Error GoTo EndNow Set Request = CreateObject（“WinHttp.WinHttpRequest.5.1”） with Request .打开 “GET”， url， False 。发送 rc = .StatusText End with set request = Nothing 如果 rc = “OK” then URLExists = true 退出函数 EndNow：结束函数

答：

1赞 taller 11/9/2023 #1

CheckConn返回 HTTP 状态代码和重定向的 URL。如果 URL 不可访问，则 HTTP 状态代码将为 0。

Public Function CheckConn(sURL) As String
    Const WHR_EnableRedirects = 6
    Const WHR_URL = 1
    Dim oXmlHttp As Object, nRetVal As Integer
    On Error Resume Next
    Set oXmlHttp = CreateObject("WinHttp.WinHttpRequest.5.1")
    oXmlHttp.Option(WHR_EnableRedirects) = True
    oXmlHttp.Open "HEAD", sURL, False
    oXmlHttp.setRequestHeader "Content-Type", "text/xml"
    oXmlHttp.send ""
    nRetVal = oXmlHttp.Status
    CheckConn = "Status: " & nRetVal & ", Redirect URL:" & oXmlHttp.Option(WHR_URL)
    Set oXmlHttp = Nothing
    On Error GoTo 0
End Function
Sub demo()
    Dim sU As String
    sU = "HTTPS://apply.d.co.uk/JobDetail/9467"
    Debug.Print (CheckConn(sU))
    sU = "https://www.youtube.com/shorts/w3-yM1IjuB0"
    Debug.Print (CheckConn(sU))
End Sub

打开时超链接会更改地址

Hyperlink changes address when opening

评论

评论