vb.net 具有自定义顺序的对象列表排序-解网

问：

我有一个对象列表，我正在尝试按两个属性排序，其中一个属性按自定义顺序排序。该列表具有 ReqType 和 PartNumber 属性。ReqType 将为“M”、“B”、“S”或 null，我想按该顺序对列表进行排序。然后按 PartNumber 排序。

Input list:
PartNumber    ReqType
124           B
125           M
123           B
121           S
120           M
115            

Expected Sort:
PartNumber    ReqType
120           M
125           M
123           B
124           B
121           S
115

我从下面的代码开始，但它只是按字母顺序对 ReqType 进行排序。

Return EBom.OrderBy(Function(f) f.ReqType).ThenBy(Function(f) f.PartNumber).ToList

然后，我找到了一种使用以下代码创建自定义排序顺序的方法。尽管使用 Ebom.Sort（）似乎不允许我为 PartNumber 设置第二个排序顺序。我意识到我可能会将 PartNumber 排序添加到自定义函数中，但这似乎需要做很多工作。

EBom.Sort()
Return EBom.ToList


Implements IComparable(Of EBomList)
Public Function SortReq(other As EBomList) As Integer Implements IComparable(Of EBomList).CompareTo
    If (Me.ReqType = other.ReqType) Then
        Return 0
    ElseIf (Me.ReqType = "M") Then
        Return -1
    ElseIf (Me.ReqType = "B") Then
        If (other.ReqType = "M") Then
            Return 1
        Else
            Return -1
        End If
    ElseIf (Me.ReqType = "S") Then
        If (other.ReqType = "M" Or other.ReqType = "B") Then
            Return 1
        Else
            Return -1
        End If
    Else
        Return 1
    End If
End Function

有没有一种更简单的方法可以按自定义顺序排序，或者至少将自定义排序函数与 .thenby（.....）结合使用来获得我想要的顺序？

vb.net 列表排序

    d.Sort(Function(X As EBomList, Y As EBomList)
               Dim Tx As Integer = InStr("MBS ", X.ReqType.PadLeft(1, " "c))
               Dim Ty As Integer = InStr("MBS ", Y.ReqType.PadLeft(1, " "c))
               Select Case Tx
                   Case Is < Ty : Return -1
                   Case Is > Ty : Return 1
                   Case Else : Return X.PartNumber.CompareTo(Y.PartNumber)
               End Select
           End Function)

请注意，仅当类型代码相同时，它才需要检查零件号。

我假设你的零件号实际上是一个数字。如果它是字符串，则需要根据需要填充它。例如。

Return X.PartNumber.PadLeft(6," "c).CompareTo(Y.PartNumber.PadLeft(6," "c))

替代和更快的方法

如果您有大量数据，您可能需要考虑扩充 EBomLit 以创建排序键，而不是执行字符串搜索......

如...

Private _ReqType As String
Private _TypeKey As Integer 

Public Property ReqType As String
    Get
        Return _ReqType
    End Get
    Set(value As String)
        _ReqType = value
        _TypeKey = InStr("MBS ", value.PadLeft(1, " "c))
    End Set
End Property

Public ReadOnly Property TypeKey As Integer
    Get
        Return _TypeKey
    End Get
End Property

然后排序就变成了......

    d.Sort(Function(X As EBomList, Y As EBomList)
               Select Case X.TypeKey
                   Case Is < Y.TypeKey : Return -1
                   Case Is > Y.TypeKey : Return 1
                   Case Else : Return X.PartNumber.CompareTo(Y.PartNumber)
               End Select
           End Function)

速度更快

您甚至可以通过从带有填充的“PartNumber”的“TypeKey”中创建一个完整的排序键来进一步扩展它，并将其用作将整个 shebang 保存在 SortedDictionary 而不是 List 中的键。

0赞 Slai 2/17/2017 #2

如果这些是选项，则更容易一些：EnumTuple

Enum PartNumber As Byte : M : B : S : __ : End Enum

Dim list = New List(Of Tuple(Of PartNumber, Integer)) From {
    Tuple.Create(PartNumber.B, 124),
    Tuple.Create(PartNumber.M, 125),
    Tuple.Create(PartNumber.B, 123),
    Tuple.Create(PartNumber.S, 121),
    Tuple.Create(PartNumber.M, 120),
    Tuple.Create(PartNumber.__, 115)}

list.Sort()

For Each item In list
    Debug.Print(item.Item2 & vbTab & item.Item1.ToString.Replace("_", ""))
Next

输出：

2赞 apc 2/18/2017 #3

只需创建一个 ReqTypes 列表并查找索引：

Dim sortOrder = "MBS "

Dim sortedList = List.OrderBy(Function(x) sortOrder.IndexOf(If(x.ReqType Is Nothing, " ", x.ReqType))).ThenBy(Function(x) x.PartNumber).ToList()

注意：如果按字符以外的内容排序，则需要创建一个要比较的对象的 propper 数组/列表。

上一个：如何在 oracle 中格式化日期和时间 [复制]

下一个：如何在网页上切换此链接？

vb.net 具有自定义顺序的对象列表排序

vb.net sort list of objects with custom order

评论