提问人：Tobin Bell 提问时间：9/15/2023 最后编辑：Mayukh BhattacharyaTobin Bell 更新时间：9/15/2023 访问量：72
包含换行单元格和单行单元格的混合列的 Excel SUM 值
Excel SUM values of a mixed Column with line-broken cells AND single-line cells
问：
这很明显，但我想知道好几天：如何在Excel中对单行值和多行（Alt + Enter）值的混合列求和？
在此示例中，我想在第二列 （7.5+12+11+1.2+2.5+3） 上显示 Sum，即 37.2。应该很容易，但是我怎样才能在Excel中得到它？
我尝试了几种方法，但到目前为止没有成功。感谢您的帮助！
答：
0赞
user11222393
9/15/2023
#1
“Alt + Enter”就是这样，然后求和：CHAR(10)TEXTSPLIT
=SUM(MAP(A1:A4,LAMBDA(z,SUM(VALUE(TEXTSPLIT(z,CHAR(10),,1))))))
评论
0赞
Tobin Bell
9/15/2023
这给了我一个错误：！IMG。可能是什么问题？我使用的是 Excel 2019。
0赞
Lambda Bam
9/15/2023
您的问题是您正在使用 excel 2019。使用免费的 Excel Web 版本使该函数正常工作。
0赞
user11222393
9/15/2023
您没有在帖子中提及您的 Excel 版本，因此假设您使用的是最新版本。我的解决方案在 Excel 2019 中不起作用，请改用@Mayukh Bhattacharya 解决方案
0赞
Tobin Bell
9/16/2023
啊，我明白了，谢谢！您知道 Office 2021 是否适合这个，还是只有 Office 365 适合？
0赞
user11222393
9/16/2023
仅适用于 Excel 365，但我看到您已经提供了有效的解决方案
0赞
Lambda Bam
9/15/2023
#2
这将过滤第 15、20、21 和 22 行中的错误/空白。
=SUM(TOCOL(MAP(C3:C10,LAMBDA(m,SUM(VALUE(TEXTSPLIT(m,CHAR(10)))))),2))
2赞
Mayukh Bhattacharya
9/15/2023
#3
也许这适用于您的 Excel 版本，使用TEXTJOIN( ) & FILTERXML( )
• 细胞中使用的配方C1
=SUM(
FILTERXML(
"<m><b>" &
SUBSTITUTE(
TEXTJOIN(
CHAR(10),
,
A1:A4
),
CHAR(10),
"</b><b>"
) & "</b></m>",
"//b"
)
)
此外，在退出编辑模式时需要点击++。CTRLSHIFTENTER
使用 MS365 函数的替代方法，不带任何帮助程序函数。LAMBDA( )
• 细胞中使用的配方C1
=LET(
a,A1:A4,
b,CHAR(10),
SUM(--(TEXTSPLIT(TEXTAFTER(b&a,b,SEQUENCE(,MAX(LEN(a)-LEN(SUBSTITUTE(a,b,))+1)),,,0),b))))
如果换行符数始终为 2，则。
=SUM(--TEXTSPLIT(TEXTAFTER(CHAR(10)&A1:A4,CHAR(10),{1,2},,,0),CHAR(10)))
Excel 2019 用户的另一种替代方法。
=SUMPRODUCT(IFERROR(TRIM(
MID(SUBSTITUTE(A1:A4,CHAR(10),REPT(" ",100)),COLUMN($A$1:$Z$1)*100-99,100))+0,0))
上面的公式需要在退出编辑模式时点击++。CTRLSHIFTENTER
评论
0赞
Tobin Bell
9/16/2023
虽然前 2 个不起作用，但最后一个在 Office 2019 中成功了。谢谢！
评论