提问人：Eugene S 提问时间：10/29/2023 更新时间：10/29/2023 访问量：52
根据 Excel 中其他两个集合的值的组合从集合中选取一个值
Pick a value from a set based on combination of values from two other sets in Excel
问：
我在Excel中有两列，其值如下：高，中和低。在第三列中，我需要根据以下逻辑从另一个集合（A，B，C，D）中输入一个值：
例如：
Column1 Column2 Column3
High High A
Medium High A
Medium Medium B
Low Medium C
等。。。
答：
1赞
Harun24hr
10/29/2023
#1
您可以使用嵌套函数。FILTER()
=FILTER(FILTER($B$2:$D$4,$A$2:$A$4=A9),$B$1:$D$1=B9)
或XLOOKUP()
=XLOOKUP(B9,$B$1:$D$1,XLOOKUP(A9,$A$2:$A$4,$B$2:$D$4))
对于所有版本的 Excel，请尝试
=INDEX($B$2:$D$4,MATCH(A9,$A$2:$A$4,0),MATCH(B9,$B$1:$D$1,0))
0赞
P.b
10/29/2023
#2
作为替代方案，这也可以在不查找的情况下完成，溢出组合及其值：=TEXTSPLIT(TEXTAFTER(TOCOL("|"&A2:A4&"|"&B1:D1&"|"&B2:D4),"|",SEQUENCE(,3)),"|")
或者，如果您没有起始范围：
=LET(a,{"High","Medium","Low"},
b,{"A","B","C","D"},
s,SEQUENCE(,3),
TEXTSPLIT(TEXTAFTER(TOCOL("|"&TOCOL(a)&"|"&a&"|"&INDEX(b,s+TOCOL(s)-2)),"|",s),"|"))
1赞
Mayukh Bhattacharya
10/29/2023
#3
这是使用HSTACK( ) & TOCOL( )
• 细胞中使用的配方E1
=HSTACK(
TOCOL(IFS(B2:D4<>"",A2:A4)),
TOCOL(IFS(B2:D4<>"",B1:D1)),
TOCOL(B2:D4))
评论