这是一种实际上允许围绕 Y 轴旋转 XY 平面中任何图形的方法。

"""
Rotation of a figure in the XY plane about the Y axis:
    ϕ = angle of rotation
    z' = z * cos(ϕ) - x * sin(ϕ)
    x' = z * sin(ϕ) + x * cos(ϕ)
    y' = y
"""

using Plots

# OP definition of the circle, but we put center at x, y of 4, 0
#    for the torus, otherwise we get a bit of a sphere

θ = 0:0.1:2.1π 
x = 4 .+ 2cos.(θ)  # center at (s, 0, 0)
y = 0 .+ 2sin.(θ)
# add the original z values as 0
z = zeros(length(x))
plot(x, y, z, color=:red)

# add the rotation axis
ϕ = 0:0.1:π/2 # for full torus use 2π at stop of range
xprime, yprime, zprime = Float64[], Float64[], Float64[]

for a in ϕ, i in eachindex(θ)
    push!(zprime, z[i] + z[i] * cos(a) - x[i] * sin(a))
    push!(xprime, z[i] * sin(a) + x[i] * cos(a))
    push!(yprime, y[i])
end

plot!(xprime, yprime, zprime, alpha=0.3, color=:green)

这是一种使用 Meshes 包构建网格和使用 MeshViz 包进行可视化的方法。你只需要翻译来完成你的任务。

using Meshes
using MeshViz
using LinearAlgebra
using GLMakie


# revolution of the polygon defined by (x,y) around the z-axis
# x and y have the same length
function revolution(x, y, n)
  u_ = LinRange(0, 2*pi, n+1)[1:n]
  j_ = 1:(length(x) - 1)           # subtract 1 because of periodicity
  function f(u, j)
    return [x[j] * sin(u), x[j] * cos(u), y[j]]
  end
  points = [f(u, j) for u in u_ for j in j_]
  topo = GridTopology((length(j_), n), (true, true))
  return SimpleMesh(Meshes.Point.(points), topo)
end


# define the section to be rotated: a circle
R = 3 # major radius
r = 1 # minor radius
ntheta = 100
theta_ = LinRange(0, 2*pi, ntheta)
x = [R + r*cos(theta) for theta in theta_]
y = [r*sin(theta) for theta in theta_]

# make mesh
mesh = revolution(x, y, 100)
# visualize mesh
viz(mesh)

编辑：动画

using Meshes
using MeshViz
using LinearAlgebra
using GLMakie
using Makie
using Printf

function revolutionTorus(R, r, alpha; n1=30, n2=90)
  theta_ = LinRange(0, 2, n1+1)[1:n1]
  x = [R + r*cospi(theta) for theta in theta_]
  y = [r*sinpi(theta) for theta in theta_]
  full = alpha == 2
  u_ = LinRange(0, alpha, n2 + full)[1:n2]
  function f(u, j)
    return [x[j] * sinpi(u), x[j] * cospi(u), y[j]]
  end
  points = [f(u, j) for u in u_ for j in 1:n1]
  topo = GridTopology((n1, n2 - !full), (true, full))
  return SimpleMesh(Meshes.Point.(points), topo)
end

# generates `nframes` meshes for alpha = 0 -> 2 (alpha is a multiple of pi)
R = 3
r = 1
nframes = 10
alpha_ = LinRange(0, 2, nframes+1)[2:(nframes+1)]
meshes = [revolutionTorus(R, r, alpha) for alpha in alpha_]

# draw and save the frames in a loop
for i in 1:nframes
  # make a bounding box in order that all frames have the same aspect
  fig, ax, plt = 
    viz(Meshes.Box(Meshes.Point(-4.5, -4.5, -2.5), Meshes.Point(4.5, 4.5, 2.5)); alpha = 0)
  ax.show_axis = false
  viz!(meshes[i])
  scale!(ax.scene, 1.8, 1.8, 1.8)
  png = @sprintf "revolutionTorus%02d.png" i
  Makie.save(png, fig)
end

# make GIF with ImageMagick
comm = @cmd "convert -delay 1x2 'revolutionTorus*.png' revolutionTorus.gif"
run(comm)

我对 Makie 的看法：

using GLMakie

Base.@kwdef mutable struct Torus
    R::Float64 = 2
    r::Float64 = 1
end

function generate_torus(torus::Torus, resolution=100; upto=1.0)
    u = range(0, stop=2π*upto, length=resolution) 
    v = range(0, stop=2π*upto, length=resolution) 
    x = [ ( torus.R + torus.r*cos(vᵢ) ) * cos(uᵢ) for vᵢ in v, uᵢ in u ]
    y = [ ( torus.R + torus.r*cos(vᵢ) ) * sin(uᵢ) for vᵢ in v, uᵢ in u ]
    z = [ torus.r * sin(vᵢ) for vᵢ in v, _ in u ]
    return x, y, z
end

function animate_torus(torus::Torus, filename="torus.gif")
    fig = Figure(resolution = (500, 500))
    ax = fig[1, 1] = LScene(fig)
    cam3d!(ax.scene)

    # Initialize surface plot with full torus
    x, y, z = generate_torus(torus)
    p = surface!(ax, x, y, z, colormap=:viridis, shading = false)
    # Set the limits
    xlims!(ax.scene, (-4, 4))
    ylims!(ax.scene, (-4, 4))
    zlims!(ax.scene, (-1, 1))

    record(fig, filename, range(0, stop=1, length=100)) do i
        # Update data of surface plot
        x, y, z = generate_torus(torus, upto=i)
        p[1] = x
        p[2] = y
        p[3] = z
    end
end

和情节

using Plots

Base.@kwdef mutable struct Torus
    x::Float64 = cos(0) + cos(0)*cos(0)
    y::Float64 = sin(0) + cos(0)*sin(0)
    z::Float64 = sin(0)
 end

function step!(torus::Torus, t, u; r=1)
    torus.x = r*cos(t) + cos(u)*cos(t)
    torus.y = r*sin(t) + cos(u)*sin(t)
    torus.z = sin(u)
    return torus
end

torus = Torus()
plt = plot([0], [0], [0], aspect_ratio=:equal, xlims=(-3, 3), ylims=(-3, 3), zlims=(-3, 3))
@gif for t in range(0, stop=2π, length=100)
     for u in range(0, stop=2π, length=100)
         step!(torus, t, u, r=2)
         push!(plt, torus.x, torus.y, torus.z)
     end
end every 2