检查 vb.net 控制事件的所有事件订阅者

试一试。有一个指向原始代码的链接。要进行测试，您需要一个表单和一个按钮。

Public Class Form1

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim _delegates As [Delegate] = GetEventHandler(Button1, "EventClick")
        If _delegates IsNot Nothing Then
            For Each d As [Delegate] In _delegates.GetInvocationList
                Debug.WriteLine(d.Method.Name)
            Next
        End If
    End Sub

    Private Sub Button1_FOO_(sender As Object, e As EventArgs) Handles Button1.Click
    End Sub

    ' from https://www.vbforums.com/showthread.php?525533-Retrieving-the-EventHandler-for-any-Event-by-code&p=3246140&viewfull=1#post3246140
    Private Function GetEventHandler(ByVal ctrl As Control, ByVal eventname As String) As [Delegate]
        Dim propInfo As System.Reflection.PropertyInfo
        propInfo = GetType(System.ComponentModel.Component).GetProperty("Events", Reflection.BindingFlags.NonPublic Or
                                                                                    Reflection.BindingFlags.Instance Or
                                                                                    Reflection.BindingFlags.Static)
        Dim handlerList As System.ComponentModel.EventHandlerList
        handlerList = CType(propInfo.GetValue(ctrl, Nothing), System.ComponentModel.EventHandlerList)
        Dim controlEventInfo As System.Reflection.FieldInfo
        controlEventInfo = GetType(Control).GetField(eventname, Reflection.BindingFlags.NonPublic Or
                                                                 Reflection.BindingFlags.Static)

        If controlEventInfo Is Nothing Then
            Return Nothing
            ' Throw New ArgumentException("Specified event does not exist.")
        End If

        Dim eventKey As Object = controlEventInfo.GetValue(ctrl)
        Dim EventHandlerDelegate As [Delegate] = handlerList.Item(eventKey)
        Return EventHandlerDelegate
    End Function
End Class