将事件处理程序分配给在 VBA 中动态创建的用户窗体上的控件

在工作表上捕获点击的示例。将其放在工作表模块中：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  ' e.g., range(A1:E1) is clicked
  If Not Application.Intersect(Target, Range("A1:E1")) Is Nothing Then
    MsgBox "You clicked " & Target.Address
  End If
End Sub

我知道您现在已经接受了适合您的解决方案，并且比下面的解决方案简单得多，但如果您有兴趣，这将是您问题的更直接的答案。

您需要创建一个类来处理按钮单击，因此每次单击按钮时，它都会使用类中的事件，您只需要执行此操作一次，然后为每个按钮创建一个新实例。为了防止这些类超出范围并丢失，它们需要存储在类级声明中。在下面，我稍微移动了您的代码。

在类模块中（我称之为 cButtonHandler）

Public WithEvents btn As MSForms.CommandButton

Private Sub btn_Click()
    MsgBox btn.Caption
End Sub

使用“事件”，因为它允许您将大多数事件用于控件。我已将按钮生成代码移动到用户窗体中，如下所示：

Dim collBtns As Collection

Private Sub UserForm_Initialize()

Dim theLabel As Object
Dim labelCounter As Long
Dim daycell As Range
Dim btn As CommandButton
Dim btnCaption As String
'Create a variable of our events class
Dim btnH As cButtonHandler
'Create a new collection to hold the classes
Set collBtns = New Collection

For Each daycell In Range("daylist")
    btnCaption = daycell.Text
    Set theLabel = ReadingsLauncher.Controls.Add("Forms.Label.1", btnCaption, True)
    With theLabel
        .Caption = btnCaption
        .Left = 10
        .Width = 50
        .Top = 20 * labelCounter
    End With

    Set btn = ReadingsLauncher.Controls.Add("Forms.CommandButton.1", "runButton", True)
    With btn
        .Caption = "Run Macro for " & btnCaption
        .Left = 80
        .Width = 80
        .Top = 20 * labelCounter
        'Create a new instance of our events class
        Set btnH = New cButtonHandler
        'Set the button we have created as the button in the class
        Set btnH.btn = btn
        'Add the class to the collection so it is not lost
        'when this procedure finishes
        collBtns.Add btnH
    End With

    labelCounter = labelCounter + 1
Next daycell


End Sub

然后，我们可以从一个单独的例程中调用 useform：

Sub addLabel()
ReadingsLauncher.Show vbModeless

End Sub

许多 VBA 书籍中都没有特别详细地介绍 VBA 中的类（通常您需要阅读 VB6 书籍才能理解），但是一旦您了解了它们以及它们的工作原理，它们就会变得非常有用:)

希望这会有所帮助

编辑 - 解决其他查询

若要引用集合中的对象，可以通过键或索引来完成。若要使用密钥，需要在将项添加到集合时添加它，因此：

collBtns.Add btnH

会变成

collBtns.Add btnH, btnCaption

因此，密钥必须是唯一的。然后，您可以参考如下：

'We refer to objects in a collection via the collection's key
'Or by it's place in the collection
'So either:
MsgBox collBtns("Monday").btn.Caption
'or:
MsgBox collBtns(1).btn.Caption
'We can then access it's properties and methods
'N.B you won't get any intellisense
collBtns("Monday").btn.Enabled = False

如果需要，您还可以向类添加其他属性/方法，例如：

Public WithEvents btn As MSForms.CommandButton

Private Sub btn_Click()
    MsgBox btn.Caption
End Sub

Public Property Let Enabled(value As Boolean)
    btn.Enabled = value
End Property

然后将访问：

collBtns("Monday").Enabled = False

这有帮助吗？为了进一步阅读，我会向你指出 Chip Pearson 的网站，他在大多数主题上都有很棒的东西 http://www.cpearson.com/excel/Events.aspx

请记住，VBA 是基于 VB6 的，因此不是一个成熟的 OO 语言，例如，它不支持正常意义上的继承，只支持接口继承

希望这对:)有所帮助