实现“依赖注入”的技术

问：

我所说的“依赖注入”是指将某种指针传递给代码的 OO 概念。在 FP 中，这将使用高阶函数来完成。

在 xslt 2+ 中，似乎有这些替代方案

• 传递函数（根据函数式编程）
• 传递 psuedo 'modes'，即传递一个显式构造的元素（或嵌入在某个节点结构中的值）并匹配它。

（还有其他替代方案可以使用include/import静态注入代码，其中include样式表中的模板会覆盖包含的样式表或与包含的样式表进行交互，但这更类似于“模板方法”，即静态组合）

XSLT 社区中是否有这方面的惯用/模式？

（能够以某种方式“捆绑”注入会很好，就像接口或类型类一样，这似乎可以通过将“模式”作为元素或值嵌入到另一个元素中来使用 psuedo 模式技术，或者“模式”是“捆绑”，但显然不是直接使用函数）

我没有给出明确的例子，如果你需要它们来说明我的意思，请告诉我。

实际上还有第三种选择，你返回一个 DSL，然后“解释它”，不同的上下文以不同的方式解释，这可能类似于“流水线”技术，虽然我非常喜欢它，但当你只想注入一个微小的细微差别时，它有点矫枉过正。

例子：

（都使用此 XML - 这无关紧要

<root>
    <foo/>
</root>

)

#1 “高阶函数”（我认为这可能是从 Martin Honnen 之前对 HOF 的回答中窃取的）

函数“apply-function”允许“注入”一个函数，然后它执行，显然任何具有兼容签名的函数都可以被注入。这是默认的 FP 技术。

<xsl:stylesheet version="3.0" 
    xmlns:my="my"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    
    <!-- Define a function that accepts a function parameter -->
    <xsl:function name="my:apply-function" as="xs:integer">
        <xsl:param name="input" as="xs:integer"/>
        <xsl:param name="function" as="function(xs:integer) as xs:integer"/>
        <xsl:sequence select="$function($input)"/>
    </xsl:function>
    
    <!-- Define a sample function to be passed as a parameter -->
    <xsl:function name="my:double" as="xs:integer">
        <xsl:param name="value" as="xs:integer"/>
        <xsl:sequence select="$value * 2"/>
    </xsl:function>
    
    <!-- Main template -->
    <xsl:template match="/">
        <result>
            <!-- Call my:apply-function and pass my:double as a parameter -->
            <xsl:variable name="result" select="my:apply-function(5, my:double#1)"/>
            <doubled-value>
                <xsl:value-of select="$result"/>
            </doubled-value>
        </result>
    </xsl:template>
</xsl:stylesheet>

#2 “伪装模式”

这样，你就可以在某个结构中显式地对你的“选择”进行编码，然后匹配它。

即“函数指针”被编码为

<Mode value='double'/>

我怀疑这种技术有更好的标签，但对我来说，模拟运行时“模式”感觉像是一种机械主义。

<xsl:stylesheet version="3.0" 
    xmlns:my="my"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    
    <xsl:template mode="inject" match="Mode[@value = 'double']">
        <xsl:param name="value" as="xs:integer"/>
        <xsl:sequence select="$value * 2"/>
    </xsl:template>

    <xsl:template mode="inject" match="Mode[@value = 'treble']">
        <xsl:param name="value" as="xs:integer"/>
        <xsl:sequence select="$value * 3"/>
    </xsl:template>
    
    <!-- Main template -->
    <xsl:template match="/">
        <result>
            <doubled-value>
                <xsl:variable name="mode">
                    <Mode value='double'/>
                </xsl:variable>
                <xsl:apply-templates mode="inject" select="$mode">
                    <xsl:with-param name="value" select="5"/>                    
                </xsl:apply-templates>
            </doubled-value>
        </result>
    </xsl:template>
</xsl:stylesheet>

#3 DSL/解释器

在这里，“callee”代码返回一些由my：makeDSL编码为xml的领域特定语言，然后由客户端特定的intepreter解释。

在这里，depedency并没有真正注入，它被外化，然后以被调用者想要的方式被嵌入，但结果是一样的。

（“nop”说明仅供说明）

<xsl:stylesheet version="3.0" 
    xmlns:my="my"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    
    <xsl:template mode="inject" match="Mode[@value = 'double']">
        <xsl:param name="value" as="xs:integer"/>
        <xsl:sequence select="$value * 2"/>
    </xsl:template>

    <xsl:template mode="inject" match="Mode[@value = 'treble']">
        <xsl:param name="value" as="xs:integer"/>
        <xsl:sequence select="$value * 3"/>
    </xsl:template>
    
    <xsl:template mode="double" match="nop"/>
        
    <xsl:template mode="double" match="inject">
        <xsl:sequence select="2 * @value"/>
    </xsl:template>
    
    <xsl:template mode="treble" match="nop"/>
    
    <xsl:template mode="treble" match="inject">
        <xsl:sequence select="3 * @value"/>
    </xsl:template>
    
    <!-- Main template -->
    <xsl:template match="/">
        <result>
            <doubled-value>
                <xsl:apply-templates mode="double" select="my:makeDSL(5)"/>
            </doubled-value>
        </result>
    </xsl:template>
    
    <xsl:function name="my:makeDSL">
        <xsl:param name="value"/>
        <nop/>
        <inject value="{$value}"/>
        <nop/>
    </xsl:function>
</xsl:stylesheet>