如何从 VBA 函数返回结果

对于非对象返回类型，必须将值分配给函数的名称，如下所示：

Public Function test() As Integer
    test = 1
End Function

用法示例：

Dim i As Integer
i = test()

如果函数返回 Object 类型，则必须使用如下关键字：Set

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

用法示例：

Dim r As Range
Set r = testRange()

请注意，为函数名称分配返回值不会终止函数的执行。如果要退出函数，则需要明确说明。例如：Exit Function

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

文档：函数语句

VBA 函数将函数名称本身视为一种变量。因此，与其使用 “” 语句，不如说：return

test = 1

但请注意，这不会超出函数。此语句之后的任何代码也将被执行。因此，您可以有许多赋值语句，这些赋值语句将不同的值赋值给 ，并且当您到达函数末尾时，无论该值是什么，都将是返回的值。test

仅仅将返回值设置为函数名称仍然与 Java（或其他）语句不完全相同，因为在 java 中，退出函数，如下所示：returnreturn

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

在 VB 中，如果您没有在函数末尾设置返回值，则精确等效值需要两行。因此，在 VB 中，确切的推论如下所示：

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

既然是这种情况，那么很高兴知道您可以像使用方法中的任何其他变量一样使用返回变量。喜欢这个：

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

或者，返回变量如何工作的极端例子（但不一定是你应该如何实际编码的好例子）——一个会让你夜不能寐的例子：

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function