在 Word 文档中存储多个位置

您可以尝试如下操作：

Option Explicit

Dim col As Collection 'global to store ranges

Sub findAndStore()
    Dim pgf As Paragraph
    Set col = New Collection
    For Each pgf In ActiveDocument.Paragraphs
        If pgf.Range.Text = "[table]" & vbCr Then
            col.Add pgf.Range.Duplicate 'store a copy of `rng`
        End If
    Next
End Sub

Sub addTables()
    Dim rng As Range
    For Each rng In col 'loop through saved ranges
        AddTable rng
    Next rng
End Sub

'dummy sub
Sub AddTable(rng As Range)
    ActiveDocument.Tables.Add rng, 2, 5
End Sub

• 利用书签标记位置，然后在插入表格后删除书签。
• 书签存储在文档中，确保即使在重新打开文档时也能保留书签。

Option Explicit

Sub findAndStore()
    Dim pgf As Paragraph
    Dim iIndex As Long
    For Each pgf In ActiveDocument.Paragraphs
        If pgf.Range.Text = "[table]" & vbCr Then
            ' Insert Bookmark
            With ActiveDocument.Bookmarks
                .Add Range:=pgf.Range, Name:="TableBK" & iIndex
                .DefaultSorting = wdSortByName
                .ShowHidden = False
            End With
            iIndex = iIndex + 1
        End If
    Next
End Sub

Sub addTables()
    Dim oBK As Bookmark
    ' Loop through bookmark and insert table
    For Each oBK In ActiveDocument.Bookmarks
        Call AddTable(oBK.Range)
        oBK.Delete
    Next
End Sub

' Add table next to [table]
Sub AddTable(BKRng As Range)
    Dim tabRng As Range
    Set tabRng = ActiveDocument.Range(BKRng.End, BKRng.End)
    ActiveDocument.Tables.Add Range:=tabRng, _
         NumRows:=2, NumColumns:=2, _
         DefaultTableBehavior:=wdWord9TableBehavior, _
         AutoFitBehavior:=wdAutoFitFixed
End Sub