如何使用UTL_HTTP包在pl / sql过程中调用HTTPS Api？

最近遇到了一些问题。不确定这是否对您有所帮助，但以下是我为使其正常工作所做的工作：

1. 为钱包创建了新文件夹（类似于：C：\some_dir\wallets）

• 为调用 API 的用户提供完全控制权限（文件夹属性 - 安全选项卡）

2. 添加到 .ora 文件中的钱包位置和身份验证的定义

#listener.ora
SSL_CLIENT_AUTHENTICATION = FALSE
WALLET_LOCATION =
  (SOURCE =
    (METHOD = FILE)
    (METHOD_DATA =
      (DIRECTORY = your_wallet_folder_path)
    )
  )
-------------------------------------------------------------------------------------------  
#tnsnames.ora
WALLET_LOCATION =
   (SOURCE =
     (METHOD = FILE)
     (METHOD_DATA =
       (DIRECTORY = your_wallet_folder_path)
     )
   )
------------------------------------------------------------------------------------------ 
#sqlnet.ora
WALLET_LOCATION =
   (SOURCE =
     (METHOD = FILE)
     (METHOD_DATA =
       (DIRECTORY = your_wallet_folder_path)
     )
   )
   
SQLNET.AUTHENTICATION_SERVICES = (TCPS,NTS,BEQ)
SSL_CLIENT_AUTHENTICATION = FALSE
SSL_CIPHER_SUITES = (SSL_RSA_WITH_AES_256_CBC_SHA, SSL_RSA_WITH_3DES_EDE_CBC_SHA)
-----------------------------------------------------------------------------------------

3. 从 API 地址下载并保存的证书 - 它将在下一步添加到钱包中

   • 有几种类型 - 我都得到了它们 - 有效的是链 .p7c

4. 使用 Walet Manager 应用程序创建新钱包（类型 .p12）

   • 请求的证书
   • 添加了受信任的证书扩展名 .p7c（链）
   • 打开钱包菜单并选中自动登录框
   • 保存在文件夹your_wallet_folder_path中的钱包

• 在 Oracle 文件夹下的“所有程序”菜单中找到它

5. 关于plsql代码
   • 将参数（如果有的话）直接放在 URL 中，使用特殊字符的串联，例如 &

        -- v_url  := v_endpoint || v_path || '?api-version=3.0' || '&' || 'from=hr' || '&' || 'to=en'

• 如果内容（正文）中预期，则构造 propper json 对象

Select JSON_ARRAYAGG(JSON_OBJECT(KEY 'text' VALUE 'some text in some language') RETURNING CLOB) Into v_body From Dual;

PL/SQL 代码 - 用于文本翻译 api

create or replace procedure "TEST"
is
BEGIN
    Declare
        v_key       VarChar2(64) := 'your api key';
        v_endpoint  VarChar2(64) := 'https://api.some_api_addres.com';
        v_path      VarChar2(64) := '/translate';
        v_location  VarChar2(64) := 'another api check';
      --
        v_body      CLOB := empty_clob();
        v_buffer    VarChar2(32767);
        --
        mReq        UTL_HTTP.req;
        mResp       UTL_HTTP.resp;
        v_url       VarChar2(128) := v_endpoint || v_path || '?api-version=3.0' || '&' || 'from=hr' || '&' || 'to=en';
    Begin
         Select JSON_ARRAYAGG(JSON_OBJECT(KEY 'text' VALUE 'some text in some language') RETURNING CLOB) Into v_body From Dual;

        UTL_HTTP.SET_BODY_CHARSET('UTF-8');
        UTL_HTTP.set_transfer_timeout (30);
        UTL_HTTP.SET_WALLET('file:your_wallet_folder_path', 'your_wallet_password');

        mReq := UTL_HTTP.BEGIN_REQUEST(v_url, 'POST');
        
        UTL_HTTP.SET_HEADER(mReq, 'Your-Api-Subscription-Key', v_key);
        UTL_HTTP.SET_HEADER(mReq, 'Your-Api-Some-Other-Check', v_location);
        UTL_HTTP.SET_HEADER(mReq, 'ClientTraceUUID', MK_GUID());  -- constructs uuid
        UTL_HTTP.SET_HEADER(mReq, 'Content-type', 'application/json');
        UTL_HTTP.SET_HEADER(mReq, 'Content-Length', length(v_body));
        
        UTL_HTTP.WRITE_TEXT(mReq, v_body);

        mResp := UTL_HTTP.GET_RESPONSE(mReq);

        begin
            loop
                utl_http.read_line(mResp, v_buffer);
                dbms_output.put_line(v_buffer);
            end loop;
            utl_http.end_response(mResp);
        exception
            when utl_http.end_of_body then
                utl_http.end_response(mResp);
        end;

    Exception
        WHEN OTHERS THEN
            dbms_output.put_line(utl_http.get_detailed_sqlerrm);
            utl_http.end_response(mResp);
    End;
END;