在 Delphi 中用鼠标右键单击移动无边框表单

这可以通过另一种方式完成。

在界面部分：

  TMyForm = class(TForm)
  private
    procedure WMNCHitTest(var Msg: TWMNCHitTest); message WM_NCHITTEST;
  end;

在实施部分：

procedure TMyForm.WMNCHitTest(var Msg: TWMNCHitTest);
begin
    inherited;   
    Msg.Result := HTCAPTION;
end;

如何使用C++通过鼠标右键单击移动窗口？有一个解决方案可以处理拖动本身，而不是让 Windows 来做。从 MFC 预测工作需要知道 Delphi 的 Forms 已经处理了什么，而不是过度调用 WinApi 函数。

一个主要问题是合并窗口的标题高度，这可能取决于多种因素。在我的示例中，我为一个相当大的窗口使用了一个普通的窗口，它使用没有任何主题的 Windows 7（看起来像 Windows 95）按预期工作。没有标题，或者有工具窗口，或者没有边框，或者有一个无法调整大小的窗口，需要调整对 GetSystemMetrics（） 的调用。

我合并了两者：用鼠标左键和鼠标右键拖动。尽管我仍然鼓励在拖动结束时显示一个潜在的上下文菜单（就像资源管理器在拖动文件时所做的那样），因为它仍然是一个鼠标右键，并且每个用户都希望该单击有一个弹出菜单。

我的示例也适用于两者：绑定到 a 或 本身。TWinControlTForm

unit Unit1;

interface

uses
  Windows, Messages, Classes, Controls, Forms, ExtCtrls;

const
  SC_DRAGMOVE=         SC_MOVE or $0002;  // The four low-order bits of the wParam parameter are used internally by the system
  SM_CXPADDEDBORDER=   92;

type
  TForm1= class( TForm )
    Panel1: TPanel;
    procedure Panel1MouseDown( Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
    procedure FormMouseMove( Sender: TObject; Shift: TShiftState; X, Y: Integer );
    procedure FormMouseUp( Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
  private
    vStart: TPoint;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

// Mouse button is pressed down and held
procedure TForm1.Panel1MouseDown( Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
begin
  case Button of
    mbLeft: begin  // Dragging through left mouse button
      ReleaseCapture();  // Restore normal mouse input processing; self.MouseCapture is already FALSE at this point
      self.Perform( WM_SYSCOMMAND, SC_DRAGMOVE, 0 );  // Handles all the rest of dragging the window
    end;

    mbRight: begin  // Through right mouse button
      GetCursorPos( self.vStart );  // Remember position on form, relative to screen
      self.vStart:= self.ScreenToClient( self.vStart );
      Inc( self.vStart.Y, GetSystemMetrics( SM_CYCAPTION )  // Window title height
                        + GetSystemMetrics( SM_CXPADDEDBORDER )  // Width of potential border padding
                        + GetSystemMetrics( SM_CYSIZEFRAME )  // Height of a potential window border when sizable; SM_CYEDGE is not enough
      );

      self.MouseCapture:= TRUE;  // WinApi: SetCapture( Handle )
    end;
  end;
end;

// Mouse is moved, unrelated to button status; must be handled by form, not panel
procedure TForm1.FormMouseMove( Sender: TObject; Shift: TShiftState; X, Y: Integer );
var
  pt: TPoint;
begin
  if self.MouseCapture then begin  // WinApi: GetCapture()= Handle
    GetCursorPos( pt );  // Position on desktop

    Dec( pt.X, self.vStart.X );  // Subtract relative starting position
    Dec( pt.Y, self.vStart.Y );

    MoveWindow( self.Handle, pt.X, pt.Y, self.Width, self.Height, TRUE );  // Reposition window by horizontal and vertical deltas
  end;
end;

// Mouse button is released; must be handled by form, not panel
procedure TForm1.FormMouseUp( Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
begin
  if Button= mbRight then self.MouseCapture:= FALSE;  // End dragging
end;

请注意，启动拖动绑定到控件的事件，但处理和结束拖动必须绑定到窗体的事件：OnMouseDown

object Form1: TForm1
  OnMouseMove = FormMouseMove
  OnMouseUp = FormMouseUp
  object Panel1: TPanel
    OnMouseDown = Panel1MouseDown
  end
end