Perl多重继承，两次继承相同的方法名：如何正确使用正确的方法？

子类可以执行以下操作：

package C;

our @ISA = qw(A B);

sub new {
    my $class = $_[0];
    my $self = ...;
    bless $self, $class;
    $self->A::_init();
    $self->B::_init();
    return $self;
}

如果 C 有自己的方法，我会这样写：_init

package C;

our @ISA = qw(A B);

sub new {
    my $class = $_[0];
    my $self = ...;
    bless $self, $class;
    $self->_init;
    return $self;
}

sub _init {
    my $self = shift;
    $self->A::_init();
    $self->B::_init();
    ...; # more initialization
}

您关心的问题之一似乎是确保使用动态绑定。如果使用箭头运算符 （） 调用方法，它将始终使用动态绑定。$object->f->

因此，如果调用（静态绑定）但在调用中发生，则该调用将使用动态绑定。A::_init($object)A::_init$self->f

所以在我的例子中，为什么我用 instead of ？因为前一种语法使用动态绑定，所以它只是从“A”开始方法解析，而不是从“C”开始。$self->A::_init()A::_init($self)

一个更复杂的例子：

package Grandparent {
  use Class::Tiny;  # provides `new`

  sub init {
    my $self = shift;
    print "From Grandparent\n";
  }
}

package Parent1 {
  use parent -norequire, 'Grandparent';  # provides `@ISA`
}

package Parent2 {
  use Class::Tiny;

  sub init {
    my $self = shift;
    print "From Parent2\n";
  }
}

package Child {
  use parent -norequire, 'Parent1', 'Parent2';

  sub init {
    my $self = shift;
    $self->Parent1::init();
    $self->Parent2::init();
    print "From Child\n";
  }
}

my $eg = Child->new;
$eg->init;

注意：在此示例中，继承自两个父类。它的方法通过其每个父级调用该方法，包括未定义自己的 init 方法但继承自 的类。ChildinitinitParent1Grandparent

虽然可以在类层次结构中显式调用不同的方法，但这似乎是一种反模式。如果层次结构中的某个位置发生更改，则需要调整其他位置的代码，以保持程序按预期工作。init()@ISA

Perl 在 core 中有一个叫做 mro 的模块，它提供了在 dfs（默认）和 c3 之间切换类方法解析顺序的可能性。 即使你想将 mro 保留在 dfs，你也可以使用 next：：method（） 和 maybe：：next method（） 它们总是使用 c3 mro 来解析方法调用。

下面的示例添加一个公共父类，其中包含按正确顺序调用的可继承构造函数和 init 方法。请注意，通常首先让 init 代码在父类中完成工作。

use strict;
use warnings;
use feature 'say';
use mro;
package GP;

sub new($)
{
    my $class = $_[0];
    my $self = [];
    bless $self, $class;
    $self->_init();
    return $self;
}

sub _init
{
    say 'GP::init called';
    say 'GP::init: do work';
}

package P1;
our @ISA = 'GP';
sub f($)
{
    say 'P1::f called';
}

sub _init($)
{
    my $self = shift;
    say 'P1::init called';
    $self->maybe::next::method(@_);
    say 'P1::init: do work, call ->f()';
    $self->f();
}


package P2;
our @ISA = 'GP';
sub _init($)
{
    my $self = shift;
    say 'P2::init called';
    $self->maybe::next::method(@_);
    say 'P2::init: do work';
}

package P3;

our @ISA = qw(P1 P2);

sub f($)
{
    say 'P3::f called';
}

sub _init($)
{
    my $self = shift;
    say 'P3::init called';
    $self->maybe::next::method(@_);
    say 'P3::init: do work';
}

package main;

my $o = P3->new;


# P3::init called
# P1::init called
# P2::init called
# GP::init called
# GP::init: do work
# P2::init: do work
# P1::init: do work, call ->f()
# P3::f called
# P3::init: do work