提问人：skeetastax 提问时间：8/19/2020 最后编辑：skeetastax 更新时间：8/19/2020 访问量：468
Perl：将哈希作为子哈希添加到简单哈希中
Perl: Add hash as sub hash to simple hash
问：
我看了另外两个问题，它们似乎是关于这个的，但它们有点迟钝，我无法将它们与我想做的事情联系起来，我认为这更简单。我还认为这将是一个非常常见的问题/任务的更清晰的陈述，所以我发布这个是为了像我这样的其他人的利益。
问题：
我有 3 个文件，每个文件都是一个对列表：key=value
设置1.ini
key1=val1
key2=val2
key3=val3
设置2.ini
key1=val4
key2=val5
key3=val6
设置3.ini
key1=val7
key2=val8
key3=val9
毫不奇怪，我想将这些对读入哈希值以对它们进行操作，所以......key=value
我有一个文件名的哈希值：
my %files = { file1 => 'settings1.ini'
, file2 => 'settings2.ini'
, file3 => 'settings3.ini'
};
我可以像这样遍历文件名：
foreach my $fkey (keys %files) {
say $files{$fkey};
}
还行。
现在，我想将每个文件中的对列表添加到哈希中，作为每个相应“顶级”文件名键下的子哈希，这样我就可以像这样遍历它们：key=value
foreach my $fkey (keys %files) {
say "File: $files{$fkey}";
foreach my $vkey (keys $files{$fkey}) {
say " $vkey: $files{$fkey}{$vkey}";
}
}
换句话说，我想在哈希中添加第二个级别，以便它从（假术语）单层值列表开始：
file1 => settings1.ini
file2 => settings2.ini
file3 => settings3.ini
成为多层值列表：
file1 => key1 => 'val1'
file1 => key2 => 'val2'
file1 => key3 => 'val3'
file2 => key1 => 'val4'
file2 => key2 => 'val5'
file2 => key3 => 'val6'
file3 => key1 => 'val7'
file3 => key2 => 'val8'
file3 => key3 => 'val9'
哪里：
my $fkey = 'file2';
my $vkey = 'key3';
say $files{$fkey}{$vkey};
将打印值
'val6'
顺便说一句，我试图用它来阅读成对。在单级哈希上执行此操作是可以的：File::Slurpkey=value
my %new_hash = read_file($files{$fkey}) =~ m/^(\w+)=([^\r\n\*,]*)$/img;
但是 - 为了重新表述整个问题 - 我真正想做的是将新的对哈希“嫁接到”顶部键“下”的现有文件名哈希上，作为“子/分支”子哈希。key=value$file
问题：
- 我该怎么做，如何像这样一次一层地构建多级哈希？
- 我可以这样做，而不必预先将哈希预定义为多层吗？
我和我都看过use strict;
Can't use string ("string") as a HASH ref while "strict refs" in use at script.pl line <lineno>.
我不完全明白......
编辑：
感谢 Timur Shtatland、Polar Bear 和 Dave Cross 的精彩回答。在精神上分析你的建议时，我突然想到，我原来的问题有点不一致，有点误导了你。我道歉。我想我现在也明白为什么我看到了“严格引用”错误。我做了一些改变。
请注意，我第一次提到的文件名的初始哈希是正确的。但是，后续的 foreach 示例循环是不正确的，因为我从用作第一个文件键变成了用作第一个文件键。我认为这就是 Perl 抛出错误的原因 - 因为我试图将键从初始字符串更改为指向子哈希的hash_ref（反之亦然）。%filesfile1settings1.inistrict refs
我理解正确了吗？
答：
2赞
Timur Shtatland
8/19/2020
#1
要一次构建一层哈希，请使用匿名哈希。这里的每个值都是对哈希值的引用，例如，对于：%files$files{'settings1.ini'}
# read the data into %new_hash, then:
$files{'settings1.ini'} = { %new_hash }
您无需预先将哈希预定义为多层（作为哈希的哈希）。
此外，避免重新发明轮子。使用 Perl 模块执行常见任务，在这种情况下，请考虑使用 Config：：IniFiles 来解析文件*.ini
另请参见：
匿名哈希：perlreftut
哈希的哈希：perldsc
评论
1赞
skeetastax
8/19/2020
谢谢帖木儿。我选择 .ini 文件作为示例，仅仅是因为它们是最熟悉的情况之一，但它可以是任何具有键=值对的文件。我不想重新发明轮子，所以感谢您提供该模块的链接。
1赞
skeetastax
8/19/2020
你得到投票@Timur因为它增加了一对大括号，使其成为一个匿名哈希，这:)
3赞
Polar Bear
8/19/2020
#2
有几个 CPAN 模块专门用于 ini 文件。你应该研究什么是可用的，并选择你内心渴望的东西。
否则，您可以按照以下代码段的精神编写自己的代码
use strict;
use warnings;
use feature 'say';
use Data::Dumper;
my @files = qw(settings1.ini settings2.ini settings3.ini);
my %hash;
for my $file (@files) {
$hash{$file} = read_settings($file);
}
say Dumper(\%hash);
sub read_settings {
my $fname = shift;
my %hash;
open my $fh, '<', $fname
or die "Couldn't open $fname";
while( <$fh> ) {
chomp;
my($k,$v) = split '=';
$hash{$k} = $v
}
close $fh;
return \%hash;
}
输出
$VAR1 = {
'settings1.ini' => {
'key2' => 'val2',
'key1' => 'val1',
'key3' => 'val3'
},
'settings2.ini' => {
'key2' => 'val5',
'key1' => 'val4',
'key3' => 'val6'
},
'settings3.ini' => {
'key1' => 'val7',
'key2' => 'val8',
'key3' => 'val9'
}
};
2赞
Dave Cross
8/19/2020
#3
Perl 让这样的事情变得非常简单。
#!/usr/bin/perl
use strict;
use warnings;
use feature 'say';
use Data::Dumper;
my %files;
# <> reads from the files given on the command line
# one line at a time.
while (<>) {
chomp;
my ($key, $val) = split /=/;
# $ARGV contains the name of the file that
# is currently being read.
$files{$ARGV}{$key} = $val;
}
say Dumper \%files;
按以下方式运行：
$ perl readconf settings1.ini settings2.ini settings3.ini
给出以下输出：
$VAR1 = {
'settings3.ini' => {
'key2' => 'val8',
'key1' => 'val7',
'key3' => 'val9'
},
'settings2.ini' => {
'key3' => 'val6',
'key1' => 'val4',
'key2' => 'val5'
},
'settings1.ini' => {
'key3' => 'val3',
'key1' => 'val1',
'key2' => 'val2'
}
};
评论