提问人：pbberk1406 提问时间：9/16/2023 最后编辑：cybernetic.nomadpbberk1406 更新时间：9/16/2023 访问量：85
Excel：如何将 3 列与 3 个不同的列匹配以从第四列返回值
Excel: how to match 3 columns to 3 different columns to return a value from a fourth column
问：
我需要将列 D&E&F 与 W&Y&X 匹配，以将 u 的值返回给 B
我正在尝试获得 D2&E2&F2 与 W2&X2&Y2 的精确匹配，以将 U2 （192042722757） 的值返回到 B2。
谷歌搜索发现：
=INDEX(U2:U2141,MATCH($D$1:$D$17&E1:$E$17&$F$1:W1:W2141&X1:X2141&Y1:Y2141,0))
复制和粘贴此信息非常繁琐，可以做到这一点吗？
答：
0赞
taller
9/16/2023
#1
- 在单元格 B1 上应用公式
=XLOOKUP(D1&E1&F1,$W$1:$W$10&$X$1:$X$10&$Y$1:$Y$10,$U$1:$U$10,,0)
或
=INDEX($U$1:$U$10,MATCH(D1&E1&F1,$W$1:$W$10&$X$1:$X$10&$Y$1:$Y$10,0))
- 通过单元格 B10 填充配方
评论
0赞
pbberk1406
9/19/2023
数据单元格可能是字母/数字，这些公式仍然有效吗？我已经尝试了三重检查我的条目并将格式从数字更改为常规和文本，但仍然得到“找不到”。非常感谢，感谢您的帮助。
0赞
taller
9/19/2023
是的。请在 OP 上分享您的数据和公式。
0赞
DjC
9/16/2023
#2
您也可以尝试以下任一公式：
=XLOOKUP(1, (D2=$W$2:$W$2141)*(E2=$X$2:$X$2141)*(F2=$Y$2:$Y$2141), $U$2:$U$2141, "Not Found")
或
=IFERROR(INDEX($U$2:$U$2141, MATCH(1, (D2=$W$2:$W$2141)*(E2=$X$2:$X$2141)*(F2=$Y$2:$Y$2141), 0)), "Not Found")
使用这两种方法时，lookup_value始终为 1，lookup_array是直接将 D 列与 W、E 与 X 以及 F 与 Y 进行比较的标准语句。每个条件的结果将返回 TRUE 或 FALSE，当相乘时将返回 1 和 0。当满足所有三个条件时，它将返回 TRUE x TRUE x TRUE，其计算结果为 1 x 1 x 1 = 1。这比将三列连接在一起更可靠，因为它消除了错误匹配的可能性（即：{12,0,3} 在使用串联时将与 {1,20,3} 匹配，因为两者的计算结果都是“1203”）。
评论
0赞
pbberk1406
9/19/2023
我已经尝试了这两种方法，但“找不到”我的单元格由字母/数字组成。我认为这是问题。您是否应该识别以这种方式格式化的数据。例如
0赞
pbberk1406
9/19/2023
D2=1066PPH E2=P45 F2=12H
0赞
DjC
9/19/2023
是的，无论字母/数字值如何，它都应该有效。如果未找到匹配项，一个可能的原因是您的lookup_values或lookup_arrays之一包含前导空格或尾随空格（即：“1066PPH”与“1066PPH”不匹配）。您可以尝试对数据使用 TRIM 函数来删除任何空格：=XLOOKUP(1,(D2=TRIM($W$2:$W$2141))*(E2=TRIM($X$2:$X$2141))*(F2=TRIM($Y$2:$Y$2141)),$U$2:$U$2141,"Not Found")
评论
=INDEX(U2:U2141,MATCH($D$1:$D$17&E1:$E$17&$F$1,W1:W2141&X1:X2141&Y1:Y2141,0))